Fiddle and Alternative Strings Forum

General Strings => ABC, MIDI, Scores and Backing Tracks => Topic started by: flipdievleugelt on Feb 02, 2007, 10:02:11 PM

Title: Dutch fiddle tunes
Post by: flipdievleugelt on Feb 02, 2007, 10:02:11 PM
Here are a number of Dutch fiddle tunes, some or all of which I plan to do at the Dutch fiddle workshop at the Fiddle Hell in Texel:

X:1
T: Brande Molenaer
P:3
M:4/4
L:1/8
K:Am
|: D2D2 F2 EF | G2G2 A2 GA | _B2 A2 G2 F2 | E4 D4 :|!
|: Bc d2 d2 e2 | ^c2 Bc d4 :|
|: d4 ^c2 ^c2 | d4 AB c2 | _B2 A2 G2 F2 | E4 D4 :|

X:2
T:De Strontmoolen
M:2/4
L:1/8
P:2
K:Am
A |: d2e2 | f>efd | agfe | fe/f/ dA |!
d2e2 | f>efd | agfe |1 f3 A :|2 f3 f |!
|: d2e2 | ^c>B^cd | ^cdef | e2 Af |!
d2e2 | ^c>B^cd | ^cdef |1 d3 f :|2 d4 ||

X:3
T:La Chercheuse d'Esprit
P:2
M:3/4
L:1/8
K:G
B2 |: A4 d2 | F4 G2 | AG Ac BA | B2 G2 B2 |!
 A4 d2 | F4 G2 | AG Ac BA |1 G4 B2 :|2 G4 d2 ||!
|: e3 def | g2 d2 g2 | f3 edc | B2 G2 d2 |!
e3 def | g2 d2 g2 | f3 edc |1 B4 d2 :|2 B6 ||

X:4
T:Belle Poule
P:2
M:C|
L:1/8
K:G
BcBA | GFGA | BABc | d4 | g2d2 | dBdB | dcBA | B2G2 |!
BcBA | GFGA | BABc | d4 | g2d2 | dBdB | dcBA | G4 :|!
K:Gm
BcBA | G2^F2 | G2D2 | E2D2 | ^F2G2 | ABAB | c2B2 | A4 |!
BcBA | G^FGD | G=FED | EDEG | ^FG^FG | ABAB | c2BA | G4 :|

X:5
T:Hornpijp
P:2
M:4/4
L:1/8
K:G
|: gdBd cedc | BdBd cedc | BGBG A2 A2 | BGFG AF D2 |!
gdBd cedc | BdBd cedc | Bdgb afdf | g2 g2 g4 :|!
|: afdf a2 a2 | b2 g2 g2 fg | afdf a2 a2 | bage d2 d2 |!
ecGc e2 e2 | dBGB d2 d2 | Bdgb afdf | g2 g2 g4 :|

X: 6
T:Visser Schots
M:6/8
L:1/8
P:2
K:G
g |: dBd cAc | Bcd efg | ded dcB | A2 A A2 g |!
dBd cAc | Bcd efg | ded cBA |1 GGG G2 g :|2 GGG G2 B ||!
BGB BGB | cAc cAc | Bcg dcB | AAA A2 B |!
BGB BGB | cAc cAc | ded cBA |1 GGG G2 B :|2 GGG G3 ||!

X:7
T: Jan Pierewiet
M:3/4
L:1/8
P:2
K:D
A2 |: ff f2 A2 | ff f2 A2 | ff f2 g2 | e4 A2 |!
ee e2 A2 | ee e2 A2 | ee e2 f2 |1 d4 A2 :|2 d4 dd ||!
|: d2 c2 B2 | A4 dd | d2 c2 B2 | A4 AA |!
A2 d2 e2 | f4 ff | g2 e2 c2 |1 d4 dd :|2 d6 :|

X:8
T:Boerenschots
M:4/4
L:1/8
P:4
K:D
|: A2 a2 A2 a2 | Aa Aa f2 d2 | A2 g2 A2 g2 | Ag Ag f2 d2 |!
A2 a2 A2 a2 | Aa Aa f2 d2 | cd ef ge ce | d2 f2 d4 :|!
K:A
|: e2 ^de fe ce | a2 c2 e2 ^de | f2 B2 d2 cd | e2 A2 c4 |!
e2 ^de fe ce | a2 c2 e2 cd | ^de gf e=d cB | A2 A2 A4 :|!
K:D
|: A2 a2 A2 a2 | Aa Aa f2 d2 | A2 g2 A2 g2 | Ag Ag f2 d2 |!
A2 a2 A2 a2 | Aa Aa f2 d2 | cd ef ge ce | d2 f2 d4 :|!
K:G
|: bb b2 aa a2 | gg g2 B4 | d2 c2 cB c2 | e2 d2 d^c d2 |!
bb b2 aa a2 | gg g2 B3 c | ^cd fe d=c BA | G2 G2 G4 :|!
Title: Re: Dutch fiddle tunes
Post by: fiddle4 on Feb 03, 2007, 03:21:08 PM
THANK = YOU
For all these I am going the lerarn this
one- Brande Molenaer -first ,,,
it sounds v , good and reminds
me of holland for some reason,thanks
again
jim/fiddle4.
SimplePortal 2.3.7 © 2008-2020, SimplePortal